Thank you for doing this. Feel free to incorporate the changes from here for supporting building the new react UI with version 126.

{
  lib,
  buildGoModule,
  buildNpmPackage,
  fetchFromGitHub,
  versionCheckHook,
}:

let
  version = "126";

  src = fetchFromGitHub {
    owner = "mostlygeek";
    repo = "llama-swap";
    rev = "v${version}";
    hash = "sha256-ZYGH7eAkasZ79V4DD3fuRcUUjHrvd4DPnAxcWVtkJY8=";
  };

  ui = buildNpmPackage (finalAttrs: {
    pname = "llama-swap-ui";
    inherit version src;

    postPatch = ''
      substituteInPlace vite.config.ts \
        --replace '../proxy/ui_dist' '${placeholder "out"}/ui_dist'
    '';

    sourceRoot = "source/ui";

    npmDepsHash = "sha256-smdqD1X9tVr0XMhQYpLBZ57/3iP8tYVoVJ2wR/gAC3w=";

    postInstall = ''
      rm -rf $out/lib
    '';

    meta = {
      description = "llama-swap - UI";
      license = lib.licenses.mit;
      platform = lib.platforms.linux;
    };
  });

in
buildGoModule rec {
  pname = "llama-swap";
  inherit version src;

  vendorHash = "sha256-5mmciFAGe8ZEIQvXejhYN+ocJL3wOVwevIieDuokhGU=";

  preBuild = ''
    cp -r ${ui}/ui_dist proxy/
  '';

  subPackages =
    [
      "."
      "proxy"
    ]
    ++ lib.optionals doCheck [
      "misc/process-cmd-test"
      "misc/simple-responder"
    ];

  nativeBuildInputs = [ versionCheckHook ];

  ldflags = [
    "-X main.version=${version}"
    "-X main.date=unknown"
    "-X main.commit=v${version}"
  ];

  postInstall = ''
    install -Dm444 -t $out/share/doc/${pname} *.md *.yaml
    cp -r examples $out/share/doc/${pname}/
  '';

  # need to adjust proxy/helpers_test.go for it to find the binaries
  doCheck = false;
  # if we run the tests in installCheckPhase instead, adjust this
  postCheck = ''
    rm -f $out/bin/{process-cmd-test,simple-responder}
  '';

  doInstallCheck = true;
  versionCheckProgramArg = "-version";

  meta = {
    description = "Model swapping for llama.cpp (or any local OpenAPI compatible server)";
    license = lib.licenses.mit;
    platform = lib.platforms.linux;
    mainProgram = "llama-swap";
  };
}

As for the module, I would expect it to run as a user service either here or via home-manager. Having multiple users hitting the same llama-swap instance is bound to bring pain.

Hi, thanks for the addition of the UI to the package, I was not aware of it when i created this PR 😅.
Regarding the module sorry, i am not very sure what you meant by "run as a user service here", should i just modify the service to use systemd.user.services.llama-swap to replace systemd.services.llama-swap
or do something like something like:

services.llama-swap = {
  package = pkgs.llama-swap;
  instances = {
    john = {
      enable = true;
      ...
    },
    doe = {
      enable = true;
      ...
    }
  }

I've been using llama-swap just fine on Darwin, so can we make this a unix platform instead of just linux?

Hi, thanks for the addition of the UI to the package, I was not aware of it when i created this PR 😅.

In all fairness it was only added in the next version after your initial PR so it's rather difficult to blame you for not being able to see into the future! ;-)

modify the service to use systemd.user.services.llama-swap to replace systemd.services.llama-swap

Yes, exactly this and this is why I said that it really belongs in home-manager instead, but unfortunately hm isn't a part of nixos proper so this is why this is the best alternative option.

The problem with user services in nixos is that it's a little ugly to activate for individual users and why I wouldn't personally use the nixos module but rather my home-made hm module (which I really should upstream too....)

llama-swap is a fast moving project so here are the details for v137 - feel free to adopt as you see fit.

{
  lib,
  buildGoModule,
  buildNpmPackage,
  fetchFromGitHub,
  versionCheckHook,
}:

let
  version = "137";

  src = fetchFromGitHub {
    owner = "mostlygeek";
    repo = "llama-swap";
    rev = "v${version}";
    hash = "sha256-DyAbZMTy4gvmF8HnUJ5B4ypIqhL9MDS7zBzeQfapFD8=";
  };

  ui = buildNpmPackage (finalAttrs: {
    pname = "llama-swap-ui";
    inherit version src;

    postPatch = ''
      substituteInPlace vite.config.ts \
        --replace-fail '../proxy/ui_dist' '${placeholder "out"}/ui_dist'
    '';

    sourceRoot = "source/ui";

    npmDepsHash = "sha256-smdqD1X9tVr0XMhQYpLBZ57/3iP8tYVoVJ2wR/gAC3w=";

    postInstall = ''
      rm -rf $out/lib
    '';

    meta = {
      description = "llama-swap - UI";
      license = lib.licenses.mit;
      maintainers = with lib.maintainers; [ peterhoeg ];
      platform = lib.platforms.linux;
    };
  });

in
buildGoModule rec {
  pname = "llama-swap";
  inherit version src;

  vendorHash = "sha256-nSdvqYVBBVIdoa991bLVwfHPGAO4OHzW8lEQPQ6cuMs=";

  preBuild = ''
    cp -r ${ui}/ui_dist proxy/
  '';

  subPackages =
    [
      "."
      "proxy"
    ]
    ++ lib.optionals doCheck [
      "misc/process-cmd-test"
      "misc/simple-responder"
    ];

  nativeBuildInputs = [ versionCheckHook ];

  ldflags = [
    "-X main.version=${version}"
    "-X main.date=unknown"
    "-X main.commit=v${version}"
  ];

  postInstall = ''
    install -Dm444 -t $out/share/doc/${pname} *.md *.yaml
    cp -r examples $out/share/doc/${pname}/
  '';

  # need to adjust proxy/helpers_test.go for it to find the binaries
  doCheck = false;
  # if we run the tests in installCheckPhase instead, adjust this
  postCheck = ''
    rm -f $out/bin/{process-cmd-test,simple-responder}
  '';

  doInstallCheck = true;
  versionCheckProgramArg = "-version";

  meta = {
    description = "Model swapping for llama.cpp (or any local OpenAPI compatible server)";
    license = lib.licenses.mit;
    maintainers = with lib.maintainers; [ peterhoeg ];
    platform = lib.platforms.linux;
    mainProgram = "llama-swap";
  };
}

An alternative approach is just to do the package first (which is rather uncontroversial) while we hammer out the details of the nixos module. That's your call of course.

I don't have any macs to test on, but if @jwiegley says it works then it does!

I also didn't take the time to thank for contributing your time to the project - I just noticed this is your first nixos PR so thank you!

I copied the definitions from this PR into my configuration in order to update to v137 — by changing linux to unix — and all is working well here. So if you could make that change, I'd be happy to approve and merge.

Hi, i've changed linux to unix 😄

An alternative approach is just to do the package first (which is rather uncontroversial) while we hammer out the details of the nixos module.

Would it be possible for the module to be on both home-manager and on nixos at the same time? (system service on nixos here and user service via home-manager)

I think that a common use case for llama-swap are home servers where there usually isn't a need for it to be a user service.

This would allow more convenience and flexibility for users to choose which type they want 😃