darkly{-qt5}: init at 0.5.13

pluiedev · pluiedev · commit c9b15f7862ae · 2024-12-23T19:45:13.000+08:00
diff --git a/pkgs/by-name/da/darkly-qt5/package.nix b/pkgs/by-name/da/darkly-qt5/package.nix
@@ -0,0 +1,5 @@
+{
+  darkly,
+  libsForQt5,
+}:
+darkly.override { qtPackages = libsForQt5; }
diff --git a/pkgs/by-name/da/darkly/package.nix b/pkgs/by-name/da/darkly/package.nix
@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  ninja,
+  kdePackages,
+  qtPackages ? kdePackages,
+  gitUpdater,
+}:
+let
+  qtMajorVersion = lib.versions.major qtPackages.qtbase.version;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "darkly-qt${qtMajorVersion}";
+  version = "0.5.13";
+
+  src = fetchFromGitHub {
+    owner = "Bali10050";
+    repo = "Darkly";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-XwBoNleHX9+kmVln6kEvWIuQ57D60bugRICqvpS/E7s=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+    qtPackages.wrapQtAppsHook
+    qtPackages.extra-cmake-modules
+  ];
+
+  buildInputs =
+    with qtPackages;
+    [
+      qtbase
+      kconfig
+      kcoreaddons
+      kcmutils
+      kguiaddons
+      ki18n
+      kiconthemes
+      kwindowsystem
+    ]
+    ++ lib.optionals (qtMajorVersion == "5") [
+      kirigami2
+    ]
+    ++ lib.optionals (qtMajorVersion == "6") [
+      kcolorscheme
+      kdecoration
+      kirigami
+    ];
+
+  cmakeFlags = map (v: lib.cmakeBool "BUILD_QT${v}" (v == qtMajorVersion)) [
+    "5"
+    "6"
+  ];
+
+  passthru.updateScript = gitUpdater { rev-prefix = "v"; };
+
+  meta =
+    {
+      description = "Modern style for Qt applications (fork of Lightly)";
+      homepage = "https://github.com/Bali10050/Darkly";
+      changelog = "https://github.com/Bali10050/Darkly/releases/tag/v${finalAttrs.version}";
+      platforms = lib.platforms.linux;
+      license = with lib.licenses; [ gpl2Plus ];
+      maintainers = with lib.maintainers; [ pluiedev ];
+    }
+    // lib.optionalAttrs (qtMajorVersion == "6") {
+      mainProgram = "darkly-settings6";
+    };
+})

-Original file line number
+Diff line change
@@ @@ -0,0 +1,5 @@ @@
 +{
 +  darkly,
 +  libsForQt5,
 +}:
 +darkly.override { qtPackages = libsForQt5; }